Mercurial > vim

view runtime/syntax/dosini.vim @ 35075:43739470fe40 default tip

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
runtime(asm): missing setlocal in indent plugin (#14658) Commit: https://github.com/vim/vim/commit/2e9b9e9a9ebf3fd40437260ecd6b1e23b02c636b Author: Marc Sven Schulte <167623652+msschulte@users.noreply.github.com> Date: Sun Apr 28 21:43:03 2024 +0200 runtime(asm): missing setlocal in indent plugin (https://github.com/vim/vim/issues/14658) Signed-off-by: Marc Sven Schulte <167623652+msschulte@users.noreply.github.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Sun, 28 Apr 2024 21:45:03 +0200
parents e8db0e2c86e6
children
line wrap: on
line source

" Vim syntax file
" Language:               Configuration File (ini file) for MSDOS/MS Windows
" Version:                2.3
" Original Author:        Sean M. McKee <mckee@misslink.net>
" Previous Maintainer:    Nima Talebi <nima@it.net.au>
" Current Maintainer:     Hong Xu <hong@topbug.net>
" Homepage:               http://www.vim.org/scripts/script.php?script_id=3747
" Repository:             https://github.com/xuhdev/syntax-dosini.vim
" Last Change:            2023 Aug 20


" quit when a syntax file was already loaded
if exists("b:current_syntax")
  finish
endif

" using of line-continuation requires cpo&vim
let s:cpo_save = &cpo
set cpo&vim

" shut case off
syn case ignore

syn match  dosiniLabel    "^.\{-}\ze\s*=" nextgroup=dosiniNumber,dosiniValue
syn match  dosiniValue    "=\zs.*"
syn match  dosiniNumber   "=\zs\s*\d\+\s*$"
syn match  dosiniNumber   "=\zs\s*\d*\.\d\+\s*$"
syn match  dosiniNumber   "=\zs\s*\d\+e[+-]\=\d\+\s*$"
syn region dosiniHeader   start="^\s*\[" end="\]"
syn match  dosiniComment  "^[#;].*$"
syn region dosiniSection  start="\s*\[.*\]" end="\ze\s*\[.*\]" fold
      \ contains=dosiniLabel,dosiniValue,dosiniNumber,dosiniHeader,dosiniComment

" Define the default highlighting.
" Only when an item doesn't have highlighting yet

hi def link dosiniNumber   Number
hi def link dosiniHeader   Special
hi def link dosiniComment  Comment
hi def link dosiniLabel    Type
hi def link dosiniValue    String


let b:current_syntax = "dosini"

let &cpo = s:cpo_save
unlet s:cpo_save

" vim: sts=2 sw=2 et