Mercurial > vim

view src/testdir/test_messages.vim @ 12281:2738b0cc5f64 v8.0.1020

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1020: when a timer calls getchar(1) input is overwritten commit https://github.com/vim/vim/commit/0f0f230012f5a9beb6876158a17b432534836c6f Author: Bram Moolenaar <Bram@vim.org> Date: Wed Aug 30 18:52:56 2017 +0200 patch 8.0.1020: when a timer calls getchar(1) input is overwritten Problem: When a timer calls getchar(1) input is overwritten. Solution: Increment tb_change_cnt in inchar(). (closes https://github.com/vim/vim/issues/1940)
author Christian Brabandt <cb@256bit.org>
date Wed, 30 Aug 2017 19:00:05 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction