Mercurial > vim

view src/testdir/test_messages.vim @ 8905:9200836eee15 v7.4.1739

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
commit https://github.com/vim/vim/commit/bea1ede1c59a11ca5bf9d91cd30b7b2937b9fb41 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Apr 14 19:44:36 2016 +0200 patch 7.4.1739 Problem: Messages test fails on MS-Windows. Solution: Adjust the asserts. Skip the "messages maintainer" line if not showing all messages.
author Christian Brabandt <cb@256bit.org>
date Thu, 14 Apr 2016 19:45:04 +0200
parents a410390e340b
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction