Mercurial > vim

view src/testdir/test_messages.vim @ 11537:e0eb2de60f09 v8.0.0651

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0651: build failure without the auto command feature commit https://github.com/vim/vim/commit/157069b04e64eff72d2b34a2f727dfb6e2190cf3 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Jun 22 14:56:12 2017 +0200 patch 8.0.0651: build failure without the auto command feature Problem: Build failure without the auto command feature. Solution: Add #ifdef. (closes https://github.com/vim/vim/issues/1782)
author Christian Brabandt <cb@256bit.org>
date Thu, 22 Jun 2017 15:00:04 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction