Mercurial > vim

view src/testdir/test_messages.vim @ 9452:6d5c24b8dc0e v7.4.2007

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
commit https://github.com/vim/vim/commit/fc4ad616073a169badfb2b9906fee2844f76f730 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Jul 9 15:38:32 2016 +0200 patch 7.4.2007 Problem: Running the tests leaves a viminfo file behind. Solution: Make the viminfo option empty.
author Christian Brabandt <cb@256bit.org>
date Sat, 09 Jul 2016 15:45:07 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction