Mercurial > vim

view src/testdir/test_messages.vim @ 11549:f5add45f9848 v8.0.0657

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0657: cannot get and set quickfix list items commit https://github.com/vim/vim/commit/6a8958db259d4444da6e6956e54a6513c1af8860 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Jun 22 21:33:20 2017 +0200 patch 8.0.0657: cannot get and set quickfix list items Problem: Cannot get and set quickfix list items. Solution: Add the "items" argument to getqflist() and setqflist(). (Yegappan Lakshmanan)
author Christian Brabandt <cb@256bit.org>
date Thu, 22 Jun 2017 21:45:03 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction