Mercurial > vim

view src/testdir/test_messages.vim @ 12126:bb43ab26381e v8.0.0943

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0943: MS-Windows: Test_terminal_scrape_multibyte may fail commit https://github.com/vim/vim/commit/3678393baa2fbfcd5020fcf0ac12947fc485e912 Author: Bram Moolenaar <Bram@vim.org> Date: Mon Aug 14 23:07:30 2017 +0200 patch 8.0.0943: MS-Windows: Test_terminal_scrape_multibyte may fail Problem: Test_terminal_scrape_multibyte fails if the codepage is not utf-8. Solution: Start "cmd" with the utf-8 codepage. (micbou, closes https://github.com/vim/vim/issues/1975)
author Christian Brabandt <cb@256bit.org>
date Mon, 14 Aug 2017 23:15:04 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction