Mercurial > vim

view src/testdir/test_messages.vim @ 9746:ab96eb561a7e v7.4.2148

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
commit https://github.com/vim/vim/commit/edf634e0f1985c5ea1afb5b480b47a44cabbce34 Author: Bram Moolenaar <Bram@vim.org> Date: Tue Aug 2 23:01:40 2016 +0200 patch 7.4.2148 Problem: Not much testing for cscope. Solution: Add a test that uses the cscope program. (Christian Brabandt)
author Christian Brabandt <cb@256bit.org>
date Tue, 02 Aug 2016 23:15:06 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction