Mercurial > vim

view src/testdir/test_messages.vim @ 13072:50aa6da392ce v8.0.1411

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1411: reading invalid memory with CTRL-W : commit https://github.com/vim/vim/commit/2efb323e875d2852f63e41c40641760d1d6b069f Author: Bram Moolenaar <Bram@vim.org> Date: Tue Dec 19 12:27:23 2017 +0100 patch 8.0.1411: reading invalid memory with CTRL-W : Problem: Reading invalid memory with CTRL-W :. Solution: Correct the command characters. (closes https://github.com/vim/vim/issues/2469)
author Christian Brabandt <cb@256bit.org>
date Tue, 19 Dec 2017 12:30:05 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction