Mercurial > vim

view src/testdir/test_messages.vim @ 13406:4e30f3f4cb78 v8.0.1577

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1577: virtual replace test fails on MS-Windows commit https://github.com/vim/vim/commit/e7808481507b9e11ae73c8f865e95eb2d20f6cc8 Author: Bram Moolenaar <Bram@vim.org> Date: Tue Mar 6 13:17:23 2018 +0100 patch 8.0.1577: virtual replace test fails on MS-Windows Problem: Virtual replace test fails on MS-Windows. Solution: Make adding a termcap entry work for a builtin terminal. Restore terminal keys in a better way.
author Christian Brabandt <cb@256bit.org>
date Tue, 06 Mar 2018 13:30:06 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction