Mercurial > vim

view src/testdir/test_messages.vim @ 8981:3b51b0aeb9a3 v7.4.1776

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
commit https://github.com/vim/vim/commit/a1c487eef71d1673e57511453009de9cb4c9af51 Author: Bram Moolenaar <Bram@vim.org> Date: Fri Apr 22 20:20:19 2016 +0200 patch 7.4.1776 Problem: Using wrong buffer length. Solution: use the right name. (Kazunobu Kuriyama)
author Christian Brabandt <cb@256bit.org>
date Fri, 22 Apr 2016 20:30:05 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction