Mercurial > vim

view src/testdir/test_messages.vim @ 13956:300aab3275c0 v8.0.1848

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1848: 'termwinscroll' does not work properly commit https://github.com/vim/vim/commit/4d6cd291cec668b991f2b43d76c6feab8b2e7d98 Author: Bram Moolenaar <Bram@vim.org> Date: Tue May 15 23:53:26 2018 +0200 patch 8.0.1848: 'termwinscroll' does not work properly Problem: 'termwinscroll' does not work properly. (Dominique Pelle) Solution: Subtract removed scrollback from the scrollback count. Add a test for 'termwinscroll'. (closes #2909)
author Christian Brabandt <cb@256bit.org>
date Wed, 16 May 2018 00:00:12 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction