Mercurial > vim

view src/testdir/test_messages.vim @ 8941:0e7b1897ceb3 v7.4.1756

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
commit https://github.com/vim/vim/commit/a6e42501424f6670fa864c739d2dc2eb764900b9 Author: Bram Moolenaar <Bram@vim.org> Date: Wed Apr 20 16:19:52 2016 +0200 patch 7.4.1756 Problem: "dll" options are not expanded. Solution: Expand environment variables. (Ozaki Kiichi)
author Christian Brabandt <cb@256bit.org>
date Wed, 20 Apr 2016 16:30:06 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction