view runtime/autoload/freebasic.vim @ 34543:748a8a413816 v9.1.0173

patch 9.1.0173: msgfmt ver. 0.22 forcibly converts text to UTF-8 Commit: https://github.com/vim/vim/commit/e498cafe74e9073a9f8134f04c22b61d7bc68894 Author: RestorerZ <restorer@mail2k.ru> Date: Tue Mar 12 22:11:36 2024 +0100 patch 9.1.0173: msgfmt ver. 0.22 forcibly converts text to UTF-8 Problem: msgfmt ver. 0.22 forcibly converts text to UTF-8 Solution: use '--no-convert' if msgfmt supports it. Add a configure check for the msgfmt version (RestorerZ). closes: #14163 Co-authored-by: Christian Brabandt <cb@256bit.org> Signed-off-by: RestorerZ <restorer@mail2k.ru> Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Tue, 12 Mar 2024 22:30:03 +0100
parents 912224cab37f
children
line wrap: on
line source

" Vim filetype plugin file
" Language:	FreeBASIC
" Maintainer:	Doug Kearns <dougkearns@gmail.com>
" Last Change:	2022 June 24

" Dialects can be one of fb, qb, fblite, or deprecated
" Precedence is forcelang > #lang > lang
function! freebasic#GetDialect() abort
  if exists("g:freebasic_forcelang")
    return g:freebasic_forcelang
  endif

  if exists("g:freebasic_lang")
    let dialect = g:freebasic_lang
  else
    let dialect = "fb"
  endif

  " override with #lang directive or metacommand

  let pat = '\c^\s*\%(#\s*lang\s\+\|''\s*$lang\s*:\s*\)"\([^"]*\)"'

  let save_cursor = getcurpos()
  call cursor(1, 1)
  let lnum = search(pat, 'cn')
  call setpos('.', save_cursor)

  if lnum
    let word = matchlist(getline(lnum), pat)[1]
    if word =~? '\<\%(fb\|deprecated\|fblite\|qb\)\>'
      let dialect = word
    else
      echomsg "freebasic#GetDialect: Invalid lang, found '" .. word .. "' at line " .. lnum .. " " .. getline(lnum)
    endif
  endif

  return dialect
endfunction

" vim: nowrap sw=2 sts=2 ts=8 noet fdm=marker: