patch 9.1.0171: Small split-move related improvements Commit: https://github.com/vim/vim/commit/5cac1a9bee0798d70a7fd80363a1f697759638e8 Author: Sean Dewar <6256228+seandewar@users.noreply.github.com> Date: Tue Mar 12 21:11:39 2024 +0100 patch 9.1.0171: Small split-move related improvements Problem: small improvements can be made to split-move related functions. Solution: apply them (Sean Dewar): - Improve some doc comments (frame_flatten should still work for non-current tabpages, despite the topframe check, which looks benign, though I'm unsure if it's still needed; see #2467). - f_win_splitmove should check_split_disallowed on wp, not targetwin, as that's what win_splitmove checks (though it's probably unnecessary to check b_locked_split at all; see #14109, which I hope to get around to finishing at some point). - Make winframe_restore restore window positions for the altframe, which winframe_remove changes. This doesn't affect the prior behaviour, as we called win_comp_pos after, but as win_comp_pos only works for curtab, and winframe_remove supports non-current tabpages, we should undo it. Regardless, this should mean we don't need win_comp_pos anymore; adjust tests to check that window positions remain unchanged. I'm not sure win_comp_pos is needed after last_status anyway if it doesn't steal rows from another frame to make room for a new statusline, which shouldn't be the case after winframe_remove? To be safe, I'll leave it as is. closes: #14185 Signed-off-by: Sean Dewar <6256228+seandewar@users.noreply.github.com> Signed-off-by: Christian Brabandt <cb@256bit.org>

vim9script

# Vim filetype plugin file
# Language: gdscript (Godot game engine scripting language)
# Maintainer: Maxim Kim <habamax@gmail.com>
# Website: https://github.com/habamax/vim-gdscript

if exists("b:did_ftplugin") | finish | endif

b:did_ftplugin = 1
b:undo_ftplugin = 'setlocal cinkeys<'
      \ .. '| setlocal indentkeys<'
      \ .. '| setlocal commentstring<'
      \ .. '| setlocal suffixesadd<'
      \ .. '| setlocal foldexpr<'
      \ .. '| setlocal foldignore<'

setlocal cinkeys-=0#
setlocal indentkeys-=0#
setlocal suffixesadd=.gd
setlocal commentstring=#\ %s
setlocal foldignore=
setlocal foldexpr=GDScriptFoldLevel()


def GDScriptFoldLevel(): string
    var line = getline(v:lnum)
    if line =~? '^\s*$'
        return "-1"
    endif

    var sw = shiftwidth()
    var indent = indent(v:lnum) / sw
    var indent_next = indent(nextnonblank(v:lnum + 1)) / sw

    if indent_next > indent && line =~ ':\s*$'
        return $">{indent_next}"
    else
        return $"{indent}"
    endif
enddef


if !exists("g:no_plugin_maps")
    # Next/Previous section
    def NextSection(back: bool, cnt: number)
        for n in range(cnt)
            search('^\s*func\s', back ? 'bW' : 'W')
        endfor
    enddef

    nnoremap <silent><buffer> ]] <scriptcmd>NextSection(false, v:count1)<CR>
    nnoremap <silent><buffer> [[ <scriptcmd>NextSection(true, v:count1)<CR>
    xmap <buffer><expr> ]] $'<C-\><C-N>{v:count1}]]m>gv'
    xmap <buffer><expr> [[ $'<C-\><C-N>{v:count1}[[m>gv'
    b:undo_ftplugin ..=
          \    " | silent exe 'unmap <buffer> [['"
          \ .. " | silent exe 'unmap <buffer> ]]'"
endif