Mercurial > vim

view runtime/syntax/gitattributes.vim @ 34257:8a91d18f1789 v9.1.0069

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.1.0069: ScreenLines may not be correctly initialized, causing hang Commit: https://github.com/vim/vim/commit/fd472655a93fd539c731c8daf3adc4e65ddce341 Author: Olaf Seibert <rhialto@falu.nl> Date: Thu Feb 1 21:11:16 2024 +0100 patch 9.1.0069: ScreenLines may not be correctly initialized, causing hang Problem: ScreenLines may not be correctly initialized, causing hang (Olaf Seibert, after 9.0.0220) Solution: always initialize ScreneLines when allocating a screen (Olaf Seibert) ScreenLines and related structures could be left uninitialized causing a screen update to run into an infinite loop when using latin1 encoding. Partly caused because by patch 9.0.0220, which makes mb_ptr2len return zero for NUL related: #12671 closes: #13946 Signed-off-by: Olaf Seibert <rhialto@falu.nl> Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Thu, 01 Feb 2024 21:30:02 +0100
parents fee9eccee266
children
line wrap: on
line source

" Vim syntax file
" Language:	git attributes
" Maintainer:	ObserverOfTime <chronobserver@disroot.org>
" Filenames:	.gitattributes, *.git/info/attributes
" Last Change:	2022 Sep 09

if exists('b:current_syntax')
    finish
endif

let s:cpo_save = &cpoptions
set cpoptions&vim

" Comment
syn keyword gitattributesTodo contained TODO FIXME XXX
syn match gitattributesComment /^\s*#.*/ contains=gitattributesTodo

" Pattern
syn match gitattributesPattern /^\s*#\@!\(".\+"\|\S\+\)/ skipwhite
            \ nextgroup=gitattributesAttrPrefixed,gitattributesAttrAssigned skipwhite
            \ contains=gitattributesGlob,gitattributesRange,gitattributesSeparator
syn match gitattributesGlob /\\\@1<![?*]/ contained
syn match gitattributesRange /\\\@1<!\[.\{-}\]/ contained
syn match gitattributesSeparator '/' contained

" Attribute
syn match gitattributesAttrPrefixed /[!-]\?[A-Za-z0-9_.][-A-Za-z0-9_.]*/
            \ transparent contained skipwhite
            \ nextgroup=gitattributesAttrPrefixed,gitattributesAttrAssigned
            \ contains=gitattributesPrefix,gitattributesName
syn match gitattributesAttrAssigned /[A-Za-z0-9_.][-A-Za-z0-9_.]*=\S\+/
            \ transparent contained skipwhite
            \ nextgroup=gitattributesAttrPrefixed,gitattributesAttrAssigned
            \ contains=gitattributesName,gitattributesAssign,gitattributesBoolean,gitattributesString
syn match gitattributesName /[A-Za-z0-9_.][-A-Za-z0-9_.]*/
            \ contained nextgroup=gitattributesAssign
syn match gitattributesPrefix /[!-]/ contained
            \ nextgroup=gitAttributesName
syn match gitattributesAssign '=' contained
            \ nextgroup=gitattributesBoolean,gitattributesString
syn match gitattributesString /=\@1<=\S\+/ contained
syn keyword gitattributesBoolean true false contained

" Macro
syn match gitattributesMacro /^\s*\[attr\]\s*\S\+/
            \ nextgroup=gitattributesAttribute skipwhite

hi def link gitattributesAssign Operator
hi def link gitattributesBoolean Boolean
hi def link gitattributesComment Comment
hi def link gitattributesGlob Special
hi def link gitattributesMacro Define
hi def link gitattributesName Identifier
hi def link gitattributesPrefix SpecialChar
hi def link gitattributesRange Special
hi def link gitattributesSeparator Delimiter
hi def link gitattributesString String
hi def link gitattributesTodo Todo

let b:current_syntax = 'gitattributes'

let &cpoptions = s:cpo_save
unlet s:cpo_save