Mercurial > vim

view runtime/ftplugin/pod.vim @ 32881:ec310fcd2d12 v9.0.1749

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.1749: Text property highlight doesn't override a sign highlight on TAB Commit: https://github.com/vim/vim/commit/dbeadf05b6a152e7d9c5cc23d9202057f8e99884 Author: Christian Brabandt <cb@256bit.org> Date: Sat Aug 19 15:35:04 2023 +0200 patch 9.0.1749: Text property highlight doesn't override a sign highlight on TAB Problem: Text property highlight doesn't override a sign highlight over a tab character Solution: Let text_property override tab highlighting This fixes a few problems of text properties: - text property highlighting when override=true does not overwrite TAB highlighting - text property highlighting when override=true does not overwrite TAB highlighting with :set list - text property highlighting is used instead of sign highlight after the actual text ends when signs are present with linehl is set closes: #21584 closes: #21592 Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Sat, 19 Aug 2023 15:45:03 +0200
parents d1fe80fb35e6
children d84610677553
line wrap: on
line source

" Vim filetype plugin file
" Language:      Perl POD format
" Maintainer:    vim-perl <vim-perl@googlegroups.com>
" Author:        Doug Kearns <dougkearns@gmail.com>
" Homepage:      https://github.com/vim-perl/vim-perl
" Bugs/requests: https://github.com/vim-perl/vim-perl/issues
" License:       Vim License (see :help license)
" Last Change:   2021 Oct 19

if exists("b:did_ftplugin")
    finish
endif

let s:save_cpo = &cpo
set cpo-=C

setlocal comments=fb:=for\ comment
setlocal commentstring==for\ comment\ %s

let b:undo_ftplugin = "setl com< cms<"

if exists("loaded_matchit") && !exists("b:match_words")
  let b:match_words =
        \ '^=pod\>:^=cut\>,' .
        \ '^=begin\s\+\(\S\+\):^=end\s\+\1,' .
        \ '^=over\>:^=item\>:^=back\>,' .
        \ '[IBCLEFSXZ]<<\%(\s\+\|$\)\@=:\%(\s\+\|^\)\@<=>>,' .
        \ '[IBCLEFSXZ]<:>'
  let b:undo_ftplugin .= " | unlet! b:match_words"
endif

if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
  let b:browsefilter = "POD Source Files (*.pod)\t*.pod\n" .
        \              "Perl Source Files (*.pl)\t*.pl\n" .
        \              "Perl Modules (*.pm)\t*.pm\n" .
        \              "All Files (*.*)\t*.*\n"
  let b:undo_ftplugin .= " | unlet! b:browsefilter"
endif

function! s:jumpToSection(backwards)
  let flags = a:backwards ? 'bsWz' : 'sWz'
  if has('syntax_items')
    let skip = "synIDattr(synID(line('.'), col('.'), 1), 'name') !~# '\\<podCommand\\>'"
  else
    let skip = ''
  endif
  for i in range(v:count1)
    call search('^=\a', flags, 0, 0, skip)
  endfor
endfunction

if !exists("no_plugin_maps") && !exists("no_pod_maps")
  nnoremap <silent> <buffer> ]] <Cmd>call <SID>jumpToSection()<CR>
  vnoremap <silent> <buffer> ]] <Cmd>call <SID>jumpToSection()<CR>
  nnoremap <silent> <buffer> ][ <Cmd>call <SID>jumpToSection()<CR>
  vnoremap <silent> <buffer> ][ <Cmd>call <SID>jumpToSection()<CR>
  nnoremap <silent> <buffer> [[ <Cmd>call <SID>jumpToSection(1)<CR>
  vnoremap <silent> <buffer> [[ <Cmd>call <SID>jumpToSection(1)<CR>
  nnoremap <silent> <buffer> [] <Cmd>call <SID>jumpToSection(1)<CR>
  vnoremap <silent> <buffer> [] <Cmd>call <SID>jumpToSection(1)<CR>
  let b:undo_ftplugin .=
        \ " | silent! exe 'nunmap <buffer> ]]' | silent! exe 'vunmap <buffer> ]]'" .
        \ " | silent! exe 'nunmap <buffer> ][' | silent! exe 'vunmap <buffer> ]['" .
        \ " | silent! exe 'nunmap <buffer> ]]' | silent! exe 'vunmap <buffer> ]]'" .
        \ " | silent! exe 'nunmap <buffer> []' | silent! exe 'vunmap <buffer> []'"
endif

let &cpo = s:save_cpo
unlet s:save_cpo

" vim: set expandtab: