patch 9.0.1747: screenpos() may cause unnecessary redraw Commit: https://github.com/vim/vim/commit/6235a109c48ff2559eca3b16578c429ffb61eadc Author: zeertzjq <zeertzjq@outlook.com> Date: Sat Aug 19 14:12:42 2023 +0200 patch 9.0.1747: screenpos() may cause unnecessary redraw Problem: screenpos() may cause unnecessary redraw. Solution: Don't unnecessarily reset VALID_WROW flag. VALID_WROW flag is only used by two functions: validate_cursor() and cursor_valid(), and cursor_valid() is only used once in ex_sleep(). When adjust_plines_for_skipcol() was first added in patch 9.0.0640, it was called in two functions: comp_botline() and curs_rows(). - comp_botline() is called in two places: - onepage(), which resets VALID_WROW flag immediately afterwards. - validate_botline_win(), where resetting a VALID_ flag is strange. - curs_rows() is called in two places: - curs_columns(), which sets VALID_WROW flag afterwards. - validate_cline_row(), which is only used by GUI mouse focus. Therefore resetting VALID_WROW there doesn't seem to do anything useful. Also, a w_skipcol check (which resets VALID_WROW flag) was added to check_cursor_moved() in patch 9.0.0734, which seems to make more sense than resetting that flag in the middle of a computation. While at it make adjust_plines_for_skipcol() and textpos2screenpos() a bit less confusing: - Make adjust_plines_for_skipcol() return "off" instead of "n - off". - Use 0-based "row" in textpos2screenpos() until W_WINROW is added. closes: #12832 Signed-off-by: Christian Brabandt <cb@256bit.org> Co-authored-by: zeertzjq <zeertzjq@outlook.com>

" Vim indent file
" Language:    Oblivion Language (obl)
" Original Creator: Kat <katisntgood@gmail.com>
" Maintainer:  Kat <katisntgood@gmail.com>
" Created:     01 November 2021
" Last Change: 13 November 2022

if exists("b:did_indent")
  finish
endif
let b:did_indent = 1
let b:undo_indent = 'setlocal indentkeys< indentexpr<'

setlocal indentexpr=GetOblIndent()
setlocal indentkeys+==~endif,=~else,=~loop,=~end

if exists("*GetOblIndent")
  finish
endif
let s:keepcpo = &cpo
set cpo&vim

let s:SKIP_LINES = '^\s*\(;.*\)'
function! GetOblIndent()

  let lnum = prevnonblank(v:lnum - 1)
  let cur_text = getline(v:lnum)
  if lnum == 0
    return 0
  endif
  let prev_text = getline(lnum)
  let found_cont = 0
  let ind = indent(lnum)

  " indent next line on start terms
  let i = match(prev_text, '\c^\s*\(\s\+\)\?\(\(if\|while\|foreach\|begin\|else\%[if]\)\>\)')
  if i >= 0
    let ind += shiftwidth()
    if strpart(prev_text, i, 1) == '|' && has('syntax_items')
          \ && synIDattr(synID(lnum, i, 1), "name") =~ '\(Comment\|String\)$'
      let ind -= shiftwidth()
    endif
  endif
  " indent current line on end/else terms
  if cur_text =~ '\c^\s*\(\s\+\)\?\(\(loop\|endif\|else\%[if]\)\>\)'
    let ind = ind - shiftwidth()
  " if we are at a begin block just go to column 0
  elseif cur_text =~ '\c^\s*\(\s\+\)\?\(\(begin\|end\)\>\)'
    let ind = 0
  endif
  return ind
endfunction

let &cpo = s:keepcpo
unlet s:keepcpo