Mercurial > vim

view runtime/syntax/mailcap.vim @ 32331:2a096f5f527c v9.0.1497

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.1497: the ruler percentage can't be localized Commit: https://github.com/vim/vim/commit/971cd2b8bc3e3a7faa886162cd7568938c627882 Author: Emir SARI <emir_sari@icloud.com> Date: Sat Apr 29 12:09:53 2023 +0100 patch 9.0.1497: the ruler percentage can't be localized Problem: The ruler percentage can't be localized. Solution: Use a string that can be translated. (Emir Sari, closes https://github.com/vim/vim/issues/12311)
author Bram Moolenaar <Bram@vim.org>
date Sat, 29 Apr 2023 13:15:04 +0200
parents 42bf9264e64e
children
line wrap: on
line source

" Vim syntax file
" Language:	Mailcap configuration file
" Maintainer:	Doug Kearns <dougkearns@gmail.com>
" Last Change:	2013 Jun 01

if exists("b:current_syntax")
  finish
endif

syn match  mailcapComment "^#.*"

syn region mailcapString start=+"+ end=+"+ contains=mailcapSpecial oneline

syn match  mailcapDelimiter "\\\@<!;"

syn match  mailcapSpecial "\\\@<!%[nstF]"
syn match  mailcapSpecial "\\\@<!%{[^}]*}"

syn case ignore
syn match  mailcapFlag	    "\(=\s*\)\@<!\<\(needsterminal\|copiousoutput\|x-\w\+\)\>"
syn match  mailcapFieldname "\<\(compose\|composetyped\|print\|edit\|test\|x11-bitmap\|nametemplate\|textualnewlines\|description\|x-\w+\)\>\ze\s*="
syn match  mailcapTypeField "^\(text\|image\|audio\|video\|application\|message\|multipart\|model\|x-[[:graph:]]\+\)\(/\(\*\|[[:graph:]]\+\)\)\=\ze\s*;"
syn case match

hi def link mailcapComment	Comment
hi def link mailcapDelimiter	Delimiter
hi def link mailcapFlag		Statement
hi def link mailcapFieldname	Statement
hi def link mailcapSpecial	Identifier
hi def link mailcapTypeField	Type
hi def link mailcapString	String

let b:current_syntax = "mailcap"

" vim: ts=8