Mercurial > vim

view ci/appveyor.bat @ 31475:9ef91bdd1ab4 v9.0.1070

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.1070: reading beyond array size Commit: https://github.com/vim/vim/commit/b26461715be41653e5982e72c794294702ecded9 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Dec 17 15:35:43 2022 +0000 patch 9.0.1070: reading beyond array size Problem: Reading beyond array size. Solution: Only use name[0] and name[1], do not use "name" as a string.
author Bram Moolenaar <Bram@vim.org>
date Sat, 17 Dec 2022 16:45:03 +0100
parents 83bd6e25d0b6
children 52232e3ff22f
line wrap: on
line source

@echo off
:: Batch file for building/testing Vim on AppVeyor

setlocal ENABLEDELAYEDEXPANSION
cd %APPVEYOR_BUILD_FOLDER%

cd src

echo "Building MSVC 64bit console Version"
nmake -f Make_mvc.mak CPU=AMD64 ^
    OLE=no GUI=no IME=yes ICONV=yes DEBUG=no ^
    FEATURES=%FEATURE%
if not exist vim.exe (
    echo Build failure.
    exit 1
)

:: build MSVC huge version with python and channel support
:: GUI needs to be last, so that testing works
echo "Building MSVC 64bit GUI Version"
if "%FEATURE%" == "HUGE" (
    nmake -f Make_mvc.mak CPU=AMD64 ^
        OLE=no GUI=yes IME=yes ICONV=yes DEBUG=no POSTSCRIPT=yes ^
        PYTHON_VER=27 DYNAMIC_PYTHON=yes PYTHON=C:\Python27-x64 ^
        PYTHON3_VER=35 DYNAMIC_PYTHON3=yes PYTHON3=C:\Python35-x64 ^
        FEATURES=%FEATURE%
) ELSE (
    nmake -f Make_mvc.mak CPU=AMD64 ^
        OLE=no GUI=yes IME=yes ICONV=yes DEBUG=no ^
        FEATURES=%FEATURE%
)
if not exist gvim.exe (
    echo Build failure.
    exit 1
)
.\gvim -u NONE -c "redir @a | ver |0put a | wq" ver_msvc.txt || exit 1

echo "version output MSVC console"
.\vim --version || exit 1
echo "version output MSVC GUI"
type ver_msvc.txt || exit 1
cd ..