Mercurial > vim

view src/testdir/test_preview.vim @ 31033:3ad8db9a1e03 v9.0.0851

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.0851: terminal mouse test is still flaky Commit: https://github.com/vim/vim/commit/1d139a012e8b9880885c6f45796437cbee4820c7 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Nov 10 00:09:22 2022 +0000 patch 9.0.0851: terminal mouse test is still flaky Problem: Terminal mouse test is still flaky. Solution: Also use WaitForAssert().
author Bram Moolenaar <Bram@vim.org>
date Thu, 10 Nov 2022 01:15:03 +0100
parents 457ea0570b6f
children
line wrap: on
line source

" Tests for the preview window

source check.vim
CheckFeature quickfix

func Test_Psearch()
  " this used to cause ml_get errors
  help
  let wincount = winnr('$')
  0f
  ps.
  call assert_equal(wincount + 1, winnr('$'))
  pclose
  call assert_equal(wincount, winnr('$'))
  bwipe
endfunc

func Test_window_preview()
  CheckFeature quickfix

  " Open a preview window
  pedit Xa
  call assert_equal(2, winnr('$'))
  call assert_equal(0, &previewwindow)

  " Go to the preview window
  wincmd P
  call assert_equal(1, &previewwindow)
  call assert_equal('preview', win_gettype())

  " Close preview window
  wincmd z
  call assert_equal(1, winnr('$'))
  call assert_equal(0, &previewwindow)

  call assert_fails('wincmd P', 'E441:')
endfunc

func Test_window_preview_from_help()
  CheckFeature quickfix

  filetype on
  call writefile(['/* some C code */'], 'Xpreview.c', 'D')
  help
  pedit Xpreview.c
  wincmd P
  call assert_equal(1, &previewwindow)
  call assert_equal('c', &filetype)
  wincmd z

  filetype off
  close
endfunc

func Test_multiple_preview_windows()
  new
  set previewwindow
  new
  call assert_fails('set previewwindow', 'E590:')
  %bw!
endfunc

" vim: shiftwidth=2 sts=2 expandtab