view runtime/plugin/manpager.vim @ 30162:d12d9d724d27 v9.0.0417

patch 9.0.0417: Jsonnet files are not recognized Commit: https://github.com/vim/vim/commit/2a4c885d54171f68ec2c2d6eb4ae281c7fefb802 Author: =?UTF-8?q?Cezary=20Dro=C5=BCak?= <cezdro@alatek.com.pl> Date: Thu Sep 8 14:41:48 2022 +0100 patch 9.0.0417: Jsonnet files are not recognized Problem: Jsonnet files are not recognized. Solution: Add a pattern for Jsonnet files. (Cezary Dro?ak, closes https://github.com/vim/vim/issues/11073, closes #11081)
author Bram Moolenaar <Bram@vim.org>
date Thu, 08 Sep 2022 15:45:04 +0200
parents 1e9e9d89f0ee
children f68f43043842
line wrap: on
line source

" Vim plugin for using Vim as manpager.
" Maintainer: Enno Nagel <ennonagel+vim@gmail.com>
" Last Change: 2022 Jun 17

" Set up the current buffer (likely read from stdin) as a manpage
command MANPAGER call s:ManPager()

function s:ManPager()
  " global options, keep these to a minimum to avoid side effects
  if &compatible
    set nocompatible
  endif
  if exists('+viminfofile')
    set viminfofile=NONE
  endif
  syntax on

  " Make this an unlisted, readonly scratch buffer
  setlocal buftype=nofile noswapfile bufhidden=hide nobuflisted readonly

  " Is this useful?  Should allow for using K on word with a colon.
  setlocal iskeyword+=:

  " Ensure text width matches window width
  setlocal foldcolumn& nofoldenable nonumber norelativenumber

  " In case Vim was invoked with -M
  setlocal modifiable

  " Emulate 'col -b'
  silent! keepj keepp %s/\v(.)\b\ze\1?//ge

  " Remove ansi sequences
  silent! keepj keepp %s/\v\e\[%(%(\d;)?\d{1,2})?[mK]//ge

  " Remove empty lines above the header
  call cursor(1, 1)
  let n = search(".*(.*)", "c")
  if n > 1
    exe "1," . n-1 . "d"
  endif

  " Finished preprocessing the buffer, prevent any further modifications
  setlocal nomodified nomodifiable

  " Set filetype to man even if ftplugin is disabled
  setlocal iskeyword+=: filetype=man
  runtime ftplugin/man.vim
endfunction