view runtime/indent/framescript.vim @ 28265:67ef250562e5 v8.2.4658

patch 8.2.4658: org-mode files are not recognized Commit: https://github.com/vim/vim/commit/3a6f952cc87065a4cf1f6502b2054ba99fdf45ed Author: ranjithshegde <ranjithshegde@gmail.com> Date: Thu Mar 31 20:24:35 2022 +0100 patch 8.2.4658: org-mode files are not recognized Problem: Org-mode files are not recognized. Solution: Add patterns to recognize "org" files. (closes https://github.com/vim/vim/issues/10046)
author Bram Moolenaar <Bram@vim.org>
date Thu, 31 Mar 2022 21:30:03 +0200
parents 9c221ad9634a
children
line wrap: on
line source

" Vim indent file
" Language:		FrameScript
" Maintainer:		Doug Kearns <dougkearns@gmail.com>
" Previous Maintainer:	Nikolai Weibull <now@bitwi.se>
" Last Change:		24 Sep 2021

if exists("b:did_indent")
  finish
endif
let b:did_indent = 1

setlocal indentexpr=GetFrameScriptIndent()
setlocal indentkeys=!^F,o,O,0=~Else,0=~EndIf,0=~EndLoop,0=~EndSub
setlocal nosmartindent

let b:undo_indent = "setl inde< indk< si<"

if exists("*GetFrameScriptIndent")
  finish
endif

function GetFrameScriptIndent()
  let lnum = prevnonblank(v:lnum - 1)

  if lnum == 0
    return 0
  endif

  if getline(v:lnum) =~ '^\s*\*'
    return cindent(v:lnum)
  endif

  let ind = indent(lnum)

  if getline(lnum) =~? '^\s*\%(If\|Loop\|Sub\)'
    let ind = ind + shiftwidth()
  endif

  if getline(v:lnum) =~? '^\s*\%(Else\|End\%(If\|Loop\|Sub\)\)'
    let ind = ind - shiftwidth()
  endif

  return ind
endfunction