Mercurial > vim

view runtime/plugin/manpager.vim @ 25802:5ef704de7709 v8.2.3436

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.3436: check for optional bool type has confusing return type Commit: https://github.com/vim/vim/commit/a29856fcdc41541c607437629c1c1f45951100a4 Author: Bram Moolenaar <Bram@vim.org> Date: Mon Sep 13 21:36:27 2021 +0200 patch 8.2.3436: check for optional bool type has confusing return type Problem: Check for optional bool type has confusing return type. Solution: Explicitly return OK.
author Bram Moolenaar <Bram@vim.org>
date Mon, 13 Sep 2021 21:45:04 +0200
parents 29ec2c198c8d
children f3ec3c57e070
line wrap: on
line source

" Vim plugin for using Vim as manpager.
" Maintainer: Enno Nagel <ennonagel+vim@gmail.com>
" Last Change: 2020 Aug 05

command! -nargs=0 MANPAGER call s:ManPager() | delcommand MANPAGER

function! s:ManPager()
  set nocompatible
  if exists('+viminfofile')
    set viminfofile=NONE
  endif
  set noswapfile 

  setlocal ft=man
  runtime ftplugin/man.vim
  setlocal buftype=nofile bufhidden=hide iskeyword+=: modifiable

  " Emulate 'col -b'
  silent! keepj keepp %s/\v(.)\b\ze\1?//ge

  " Remove ansi sequences
  silent! keepj keepp %s/\v\e\[%(%(\d;)?\d{1,2})?[mK]//ge

  " Remove empty lines above the header
  call cursor(1, 1)
  let n = search(".*(.*)", "c")
  if n > 1
    exe "1," . n-1 . "d"
  endif
  setlocal nomodified readonly

  syntax on
endfunction