Mercurial > vim

view runtime/indent/rnoweb.vim @ 25386:9c749ad22565 v8.2.3230

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.3230: Vim9: type error when function return type is not known yet Commit: https://github.com/vim/vim/commit/f723701de0636ad8b4aad6179b322f72b04354b9 Author: Bram Moolenaar <Bram@vim.org> Date: Tue Jul 27 22:21:44 2021 +0200 patch 8.2.3230: Vim9: type error when function return type is not known yet Problem: Vim9: type error when function return type is not known yet. Solution: When return type is unknown, use "any". (closes https://github.com/vim/vim/issues/8644)
author Bram Moolenaar <Bram@vim.org>
date Tue, 27 Jul 2021 22:30:03 +0200
parents 0ecb909e3249
children b2412874362f
line wrap: on
line source

" Vim indent file
" Language:	Rnoweb
" Author:	Jakson Alves de Aquino <jalvesaq@gmail.com>
" Homepage:     https://github.com/jalvesaq/R-Vim-runtime
" Last Change:	Fri Apr 15, 2016  10:58PM


" Only load this indent file when no other was loaded.
if exists("b:did_indent")
  finish
endif
runtime indent/tex.vim

function! s:NoTeXIndent()
  return indent(line("."))
endfunction

if &indentexpr == "" || &indentexpr == "GetRnowebIndent()"
  let s:TeXIndent = function("s:NoTeXIndent")
else
  let s:TeXIndent = function(substitute(&indentexpr, "()", "", ""))
endif

unlet! b:did_indent
runtime indent/r.vim
let s:RIndent = function(substitute(&indentexpr, "()", "", ""))
let b:did_indent = 1

setlocal indentkeys=0{,0},!^F,o,O,e,},=\bibitem,=\item
setlocal indentexpr=GetRnowebIndent()

if exists("*GetRnowebIndent")
  finish
endif

function GetRnowebIndent()
  let curline = getline(".")
  if curline =~ '^<<.*>>=$' || curline =~ '^\s*@$'
    return 0
  endif
  if search("^<<", "bncW") > search("^@", "bncW")
    return s:RIndent()
  endif
  return s:TeXIndent()
endfunction

" vim: sw=2