Mercurial > vim

view runtime/syntax/mailcap.vim @ 25238:dd98794f7d8c v8.2.3155

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.3155: some option related code not covered by tests Commit: https://github.com/vim/vim/commit/042414fa0053388f9a35cad61886405507554068 Author: Dominique Pelle <dominique.pelle@gmail.com> Date: Mon Jul 12 21:43:19 2021 +0200 patch 8.2.3155: some option related code not covered by tests Problem: Some option related code not covered by tests. Solution: Add a few test cases. (Dominique Pell?, closes https://github.com/vim/vim/issues/8552)
author Bram Moolenaar <Bram@vim.org>
date Mon, 12 Jul 2021 21:45:06 +0200
parents 42bf9264e64e
children
line wrap: on
line source

" Vim syntax file
" Language:	Mailcap configuration file
" Maintainer:	Doug Kearns <dougkearns@gmail.com>
" Last Change:	2013 Jun 01

if exists("b:current_syntax")
  finish
endif

syn match  mailcapComment "^#.*"

syn region mailcapString start=+"+ end=+"+ contains=mailcapSpecial oneline

syn match  mailcapDelimiter "\\\@<!;"

syn match  mailcapSpecial "\\\@<!%[nstF]"
syn match  mailcapSpecial "\\\@<!%{[^}]*}"

syn case ignore
syn match  mailcapFlag	    "\(=\s*\)\@<!\<\(needsterminal\|copiousoutput\|x-\w\+\)\>"
syn match  mailcapFieldname "\<\(compose\|composetyped\|print\|edit\|test\|x11-bitmap\|nametemplate\|textualnewlines\|description\|x-\w+\)\>\ze\s*="
syn match  mailcapTypeField "^\(text\|image\|audio\|video\|application\|message\|multipart\|model\|x-[[:graph:]]\+\)\(/\(\*\|[[:graph:]]\+\)\)\=\ze\s*;"
syn case match

hi def link mailcapComment	Comment
hi def link mailcapDelimiter	Delimiter
hi def link mailcapFlag		Statement
hi def link mailcapFieldname	Statement
hi def link mailcapSpecial	Identifier
hi def link mailcapTypeField	Type
hi def link mailcapString	String

let b:current_syntax = "mailcap"

" vim: ts=8