Mercurial > vim

view src/testdir/test_preview.vim @ 25155:a37cf57980f9 v8.2.3114

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.3114: Amiga-like systems: build error using stat() Commit: https://github.com/vim/vim/commit/599a6e5b3629d943a795cd69e4d3d19886f86405 Author: =?UTF-8?q?Ola=20S=C3=B6der?= <rolfkopman@gmail.com> Date: Tue Jul 6 20:15:46 2021 +0200 patch 8.2.3114: Amiga-like systems: build error using stat() Problem: Amiga-like systems: build error using stat(). Solution: Only build swapfile_process_running() on systems where it is actually used. (Ola S?der, closes #8519)
author Bram Moolenaar <Bram@vim.org>
date Tue, 06 Jul 2021 20:30:03 +0200
parents 08940efa6b4e
children 457ea0570b6f
line wrap: on
line source

" Tests for the preview window

source check.vim
CheckFeature quickfix

func Test_Psearch()
  " this used to cause ml_get errors
  help
  let wincount = winnr('$')
  0f
  ps.
  call assert_equal(wincount + 1, winnr('$'))
  pclose
  call assert_equal(wincount, winnr('$'))
  bwipe
endfunc

func Test_window_preview()
  CheckFeature quickfix

  " Open a preview window
  pedit Xa
  call assert_equal(2, winnr('$'))
  call assert_equal(0, &previewwindow)

  " Go to the preview window
  wincmd P
  call assert_equal(1, &previewwindow)
  call assert_equal('preview', win_gettype())

  " Close preview window
  wincmd z
  call assert_equal(1, winnr('$'))
  call assert_equal(0, &previewwindow)

  call assert_fails('wincmd P', 'E441:')
endfunc

func Test_window_preview_from_help()
  CheckFeature quickfix

  filetype on
  call writefile(['/* some C code */'], 'Xpreview.c')
  help
  pedit Xpreview.c
  wincmd P
  call assert_equal(1, &previewwindow)
  call assert_equal('c', &filetype)
  wincmd z

  filetype off
  close
  call delete('Xpreview.c')
endfunc

func Test_multiple_preview_windows()
  new
  set previewwindow
  new
  call assert_fails('set previewwindow', 'E590:')
  %bw!
endfunc

" vim: shiftwidth=2 sts=2 expandtab