view runtime/indent/gitconfig.vim @ 23201:94608d7c3b55 v8.2.2146

patch 8.2.2146: Vim9: automatic conversion of number to string for dict key Commit: https://github.com/vim/vim/commit/9987fb0b4b591e6450fb1dfbe8f615f365057f2a Author: Bram Moolenaar <Bram@vim.org> Date: Tue Dec 15 21:41:56 2020 +0100 patch 8.2.2146: Vim9: automatic conversion of number to string for dict key Problem: Vim9: automatic conversion of number to string for dict key. Solution: Do not convert number to string. (closes https://github.com/vim/vim/issues/7474)
author Bram Moolenaar <Bram@vim.org>
date Tue, 15 Dec 2020 21:45:05 +0100
parents 63b0b7b79b25
children
line wrap: on
line source

" Vim indent file
" Language:	git config file
" Maintainer:	Tim Pope <vimNOSPAM@tpope.org>
" Last Change:	2017 Jun 13

if exists("b:did_indent")
  finish
endif
let b:did_indent = 1

setlocal autoindent
setlocal indentexpr=GetGitconfigIndent()
setlocal indentkeys=o,O,*<Return>,0[,],0;,0#,=,!^F

let b:undo_indent = 'setl ai< inde< indk<'

" Only define the function once.
if exists("*GetGitconfigIndent")
  finish
endif

function! GetGitconfigIndent()
  let sw    = shiftwidth()
  let line  = getline(prevnonblank(v:lnum-1))
  let cline = getline(v:lnum)
  if line =~  '\\\@<!\%(\\\\\)*\\$'
    " odd number of slashes, in a line continuation
    return 2 * sw
  elseif cline =~ '^\s*\['
    return 0
  elseif cline =~ '^\s*\a'
    return sw
  elseif cline == ''       && line =~ '^\['
    return sw
  else
    return -1
  endif
endfunction