Mercurial > vim

view runtime/indent.vim @ 21443:66386ca8a69f v8.2.1272

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.1272: Vim9: type not checked if declaration also assigns value Commit: https://github.com/vim/vim/commit/4cdb13ce81309b62b636f2c614241959174d3fef Author: Bram Moolenaar <Bram@vim.org> Date: Wed Jul 22 21:45:14 2020 +0200 patch 8.2.1272: Vim9: type not checked if declaration also assigns value Problem: Vim9: type not checked if declaration also assigns value. Solution: Check the type. (issue https://github.com/vim/vim/issues/6507)
author Bram Moolenaar <Bram@vim.org>
date Wed, 22 Jul 2020 22:00:04 +0200
parents 19ef2bbf569c
children f37561549ec2
line wrap: on
line source

" Vim support file to switch on loading indent files for file types
"
" Maintainer:	Bram Moolenaar <Bram@vim.org>
" Last Change:	2008 Feb 22

if exists("did_indent_on")
  finish
endif
let did_indent_on = 1

augroup filetypeindent
  au FileType * call s:LoadIndent()
  func! s:LoadIndent()
    if exists("b:undo_indent")
      exe b:undo_indent
      unlet! b:undo_indent b:did_indent
    endif
    let s = expand("<amatch>")
    if s != ""
      if exists("b:did_indent")
	unlet b:did_indent
      endif

      " When there is a dot it is used to separate filetype names.  Thus for
      " "aaa.bbb" load "indent/aaa.vim" and then "indent/bbb.vim".
      for name in split(s, '\.')
	exe 'runtime! indent/' . name . '.vim'
      endfor
    endif
  endfunc
augroup END