Mercurial > vim

view src/testdir/test_exit.vim @ 18014:82543df649ba v8.1.2003

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.2003: MS-Windows: code page 65001 is not recognized Commit: https://github.com/vim/vim/commit/fa90d70884ee208966b84052080a7d5eeb8ac2d5 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Sep 7 16:07:47 2019 +0200 patch 8.1.2003: MS-Windows: code page 65001 is not recognized Problem: MS-Windows: code page 65001 is not recognized. Solution: Use utf-8 for code page 65001. (Dan Thompson, closes https://github.com/vim/vim/issues/4902)
author Bram Moolenaar <Bram@vim.org>
date Sat, 07 Sep 2019 16:15:03 +0200
parents 9c90cf08cfa8
children fa6efc49d71f
line wrap: on
line source

" Tests for exiting Vim.

source shared.vim

func Test_exiting()
  let after =<< trim [CODE]
    au QuitPre * call writefile(["QuitPre"], "Xtestout")
    au ExitPre * call writefile(["ExitPre"], "Xtestout", "a")
    quit
  [CODE]

  if RunVim([], after, '')
    call assert_equal(['QuitPre', 'ExitPre'], readfile('Xtestout'))
  endif
  call delete('Xtestout')

  let after =<< trim [CODE]
    au QuitPre * call writefile(["QuitPre"], "Xtestout")
    au ExitPre * call writefile(["ExitPre"], "Xtestout", "a")
    help
    wincmd w
    quit
  [CODE]

  if RunVim([], after, '')
    call assert_equal(['QuitPre', 'ExitPre'], readfile('Xtestout'))
  endif
  call delete('Xtestout')

  let after =<< trim [CODE]
    au QuitPre * call writefile(["QuitPre"], "Xtestout")
    au ExitPre * call writefile(["ExitPre"], "Xtestout", "a")
    split
    new
    qall
  [CODE]

  if RunVim([], after, '')
    call assert_equal(['QuitPre', 'ExitPre'], readfile('Xtestout'))
  endif
  call delete('Xtestout')

  let after =<< trim [CODE]
    au QuitPre * call writefile(["QuitPre"], "Xtestout", "a")
    au ExitPre * call writefile(["ExitPre"], "Xtestout", "a")
    augroup nasty
      au ExitPre * split
    augroup END
    quit
    augroup nasty
      au! ExitPre
    augroup END
    quit
  [CODE]

  if RunVim([], after, '')
    call assert_equal(['QuitPre', 'ExitPre', 'QuitPre', 'ExitPre'],
	  \ readfile('Xtestout'))
  endif
  call delete('Xtestout')
endfunc