Mercurial > vim

view src/testdir/test_matchadd_conceal_utf8.vim @ 17308:d04de6c49f59 v8.1.1653

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1653: ubsan warns for possibly passing NULL pointer commit https://github.com/vim/vim/commit/0d07155c8bbaca1a527b79da358438253a60839f Author: Bram Moolenaar <Bram@vim.org> Date: Mon Jul 8 22:04:03 2019 +0200 patch 8.1.1653: ubsan warns for possibly passing NULL pointer Problem: Ubsan warns for possibly passing NULL pointer. Solution: Skip code when length is zero. (Dominique Pelle, closes https://github.com/vim/vim/issues/4631)
author Bram Moolenaar <Bram@vim.org>
date Mon, 08 Jul 2019 22:15:04 +0200
parents 8e9e9124c7a2
children 0dcc2ee838dd
line wrap: on
line source

" Test for matchadd() and conceal feature using utf-8.

source check.vim
CheckFeature conceal

if !has('gui_running') && has('unix')
  set term=ansi
endif

func s:screenline(lnum) abort
  let line = []
  for c in range(1, winwidth(0))
    call add(line, nr2char(screenchar(a:lnum, c)))
  endfor
  return s:trim(join(line, ''))
endfunc

func s:trim(str) abort
  return matchstr(a:str,'^\s*\zs.\{-}\ze\s*$')
endfunc

func Test_match_using_multibyte_conceal_char()
  new
  setlocal concealcursor=n conceallevel=1

  1put='# This is a Test'
  "             1234567890123456
  let expect = '#ˑThisˑisˑaˑTest'

  call cursor(1, 1)
  call matchadd('Conceal', '\%2l ', 20, -1, {'conceal': "\u02d1"})
  redraw!

  let lnum = 2
  call assert_equal(expect, s:screenline(lnum))
  call assert_notequal(screenattr(lnum, 1), screenattr(lnum, 2))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 7))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 10))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 12))
  call assert_equal(screenattr(lnum, 1), screenattr(lnum, 16))

  quit!
endfunc