Mercurial > vim

view runtime/indent/rnoweb.vim @ 16348:5f3a86ba4261 v8.1.1179

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1179: no test for mouse clicks in the fold column commit https://github.com/vim/vim/commit/696d6377289eb7c703263aaabe58134968335c4b Author: Bram Moolenaar <Bram@vim.org> Date: Wed Apr 17 16:33:46 2019 +0200 patch 8.1.1179: no test for mouse clicks in the fold column Problem: No test for mouse clicks in the fold column. Solution: Add a test. (Dominique Pelle, closes https://github.com/vim/vim/issues/4261)
author Bram Moolenaar <Bram@vim.org>
date Wed, 17 Apr 2019 16:45:05 +0200
parents 0ecb909e3249
children b2412874362f
line wrap: on
line source

" Vim indent file
" Language:	Rnoweb
" Author:	Jakson Alves de Aquino <jalvesaq@gmail.com>
" Homepage:     https://github.com/jalvesaq/R-Vim-runtime
" Last Change:	Fri Apr 15, 2016  10:58PM


" Only load this indent file when no other was loaded.
if exists("b:did_indent")
  finish
endif
runtime indent/tex.vim

function! s:NoTeXIndent()
  return indent(line("."))
endfunction

if &indentexpr == "" || &indentexpr == "GetRnowebIndent()"
  let s:TeXIndent = function("s:NoTeXIndent")
else
  let s:TeXIndent = function(substitute(&indentexpr, "()", "", ""))
endif

unlet! b:did_indent
runtime indent/r.vim
let s:RIndent = function(substitute(&indentexpr, "()", "", ""))
let b:did_indent = 1

setlocal indentkeys=0{,0},!^F,o,O,e,},=\bibitem,=\item
setlocal indentexpr=GetRnowebIndent()

if exists("*GetRnowebIndent")
  finish
endif

function GetRnowebIndent()
  let curline = getline(".")
  if curline =~ '^<<.*>>=$' || curline =~ '^\s*@$'
    return 0
  endif
  if search("^<<", "bncW") > search("^@", "bncW")
    return s:RIndent()
  endif
  return s:TeXIndent()
endfunction

" vim: sw=2