Mercurial > vim

view runtime/syntax/limits.vim @ 14447:f103c66ea515 v8.1.0237

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.0237: Ruby on Cygwin doesn't always work commit https://github.com/vim/vim/commit/87ea64ca965ca00b3e72776c39355964293f2ace Author: Bram Moolenaar <Bram@vim.org> Date: Sat Aug 4 15:13:34 2018 +0200 patch 8.1.0237: Ruby on Cygwin doesn't always work Problem: Ruby on Cygwin doesn't always work. Solution: Use LIBRUBY_SO if LIBRUBY_ALIASES isn't set. (Ken Takata)
author Christian Brabandt <cb@256bit.org>
date Sat, 04 Aug 2018 15:15:05 +0200
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             limits(5) configuration file
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn keyword limitsTodo    contained TODO FIXME XXX NOTE

syn region  limitsComment display oneline start='^\s*#' end='$'
                          \ contains=limitsTodo,@Spell

syn match   limitsBegin   display '^'
                          \ nextgroup=limitsUser,limitsDefault,limitsComment
                          \ skipwhite

syn match   limitsUser    contained '[^ \t#*]\+'
                          \ nextgroup=limitsLimit,limitsDeLimit skipwhite

syn match   limitsDefault contained '*'
                          \ nextgroup=limitsLimit,limitsDeLimit skipwhite

syn match   limitsLimit   contained '[ACDFMNRSTUKLP]' nextgroup=limitsNumber
syn match   limitsDeLimit contained '-'

syn match   limitsNumber  contained '\d\+\>' nextgroup=limitsLimit skipwhite

hi def link limitsTodo    Todo
hi def link limitsComment Comment
hi def link limitsUser    Keyword
hi def link limitsDefault Macro
hi def link limitsLimit   Identifier
hi def link limitsDeLimit Special
hi def link limitsNumber  Number

let b:current_syntax = "limits"

let &cpo = s:cpo_save
unlet s:cpo_save