Mercurial > vim

view runtime/syntax/services.vim @ 13206:53f0c469dfc6 v8.0.1477

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1477: redraw flicker when moving the mouse outside of terminal window commit https://github.com/vim/vim/commit/d317b38a4dbcdbd4cf587cf78cc1f4289374214e Author: Bram Moolenaar <Bram@vim.org> Date: Thu Feb 8 22:33:31 2018 +0100 patch 8.0.1477: redraw flicker when moving the mouse outside of terminal window Problem: Redraw flicker when moving the mouse outside of terminal window. Solution: Instead of updating the cursor color and shape every time leaving and entering a terminal window, only update when different from the previously used cursor.
author Christian Brabandt <cb@256bit.org>
date Thu, 08 Feb 2018 22:45:05 +0100
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             services(5) - Internet network services list
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   servicesBegin     display '^'
                              \ nextgroup=servicesName,servicesComment

syn match   servicesName      contained display '[[:graph:]]\+'
                              \ nextgroup=servicesPort skipwhite

syn match   servicesPort      contained display '\d\+'
                              \ nextgroup=servicesPPDiv,servicesPPDivDepr
                              \ skipwhite

syn match   servicesPPDiv     contained display '/'
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesPPDivDepr contained display ','
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesProtocol  contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn match   servicesAliases   contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn keyword servicesTodo      contained TODO FIXME XXX NOTE

syn region  servicesComment   display oneline start='#' end='$'
                              \ contains=servicesTodo,@Spell

hi def link servicesTodo      Todo
hi def link servicesComment   Comment
hi def link servicesName      Identifier
hi def link servicesPort      Number
hi def link servicesPPDiv     Delimiter
hi def link servicesPPDivDepr Error
hi def link servicesProtocol  Type
hi def link servicesAliases   Macro

let b:current_syntax = "services"

let &cpo = s:cpo_save
unlet s:cpo_save