Mercurial > vim

view src/testdir/test_messages.vim @ 13138:0f906f414c69 v8.0.1443

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1443: compiler complains about uninitialized variable commit https://github.com/vim/vim/commit/059fd01021779ee369c1e55557275f6c349fda9e Author: Bram Moolenaar <Bram@vim.org> Date: Wed Jan 31 14:25:53 2018 +0100 patch 8.0.1443: compiler complains about uninitialized variable Problem: Compiler complains about uninitialized variable. (Tony Mechelynck) Solution: Assign a value to the variable.
author Christian Brabandt <cb@256bit.org>
date Wed, 31 Jan 2018 14:30:05 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction