view runtime/autoload/paste.vim @ 12879:f67ac05fa3cd v8.0.1316

patch 8.0.1316: build still still fails on Mac commit https://github.com/vim/vim/commit/44c2bffde74a98acdc60505e57c70cd7cc2afa1e Author: Bram Moolenaar <Bram@vim.org> Date: Sat Nov 18 23:23:01 2017 +0100 patch 8.0.1316: build still still fails on Mac Problem: Build still still fails on Mac. (chdiza) Solution: Remove another bogus typedef.
author Christian Brabandt <cb@256bit.org>
date Sat, 18 Nov 2017 23:30:05 +0100
parents d91cf2e26ef0
children fe57e4f0eac1
line wrap: on
line source

" Vim support file to help with paste mappings and menus
" Maintainer:	Bram Moolenaar <Bram@vim.org>
" Last Change:	2017 Aug 30

" Define the string to use for items that are present both in Edit, Popup and
" Toolbar menu.  Also used in mswin.vim and macmap.vim.

" Pasting blockwise and linewise selections is not possible in Insert and
" Visual mode without the +virtualedit feature.  They are pasted as if they
" were characterwise instead.  Add to that some tricks to leave the cursor in
" the right position, also for "gi".
if has("virtualedit")
  let paste#paste_cmd = {'n': ":call paste#Paste()<CR>"}
  let paste#paste_cmd['v'] = '"-c<Esc>' . paste#paste_cmd['n']
  let paste#paste_cmd['i'] = "\<c-\>\<c-o>\"+gP"

  func! paste#Paste()
    let ove = &ve
    set ve=all
    normal! `^
    if @+ != ''
      normal! "+gP
    endif
    let c = col(".")
    normal! i
    if col(".") < c	" compensate for i<ESC> moving the cursor left
      normal! l
    endif
    let &ve = ove
  endfunc
else
  let paste#paste_cmd = {'n': "\"=@+.'xy'<CR>gPFx\"_2x"}
  let paste#paste_cmd['v'] = '"-c<Esc>gix<Esc>' . paste#paste_cmd['n'] . '"_x'
  let paste#paste_cmd['i'] = 'x<Esc>' . paste#paste_cmd['n'] . '"_s'
endif