view runtime/indent/rnoweb.vim @ 12792:f3a7ce8edce9 v8.0.1273

patch 8.0.1273: old test file remaining commit https://github.com/vim/vim/commit/4148be468f82eb4bf463be3610b00a132aee4186 Author: Bram Moolenaar <Bram@vim.org> Date: Mon Nov 6 20:41:19 2017 +0100 patch 8.0.1273: old test file remaining Problem: Old test file remaining. Solution: Delete it.
author Christian Brabandt <cb@256bit.org>
date Mon, 06 Nov 2017 20:45:04 +0100
parents 03fa8a51e9dc
children 0ecb909e3249
line wrap: on
line source

" Vim indent file
" Language:	Rnoweb
" Author:	Jakson Alves de Aquino <jalvesaq@gmail.com>
" Homepage:     https://github.com/jalvesaq/R-Vim-runtime
" Last Change:	Fri Apr 15, 2016  10:58PM


" Only load this indent file when no other was loaded.
if exists("b:did_indent")
  finish
endif
runtime indent/tex.vim

function! s:NoTeXIndent()
  return indent(line("."))
endfunction

if &indentexpr == "" || &indentexpr == "GetRnowebIndent()"
  let s:TeXIndent = function("s:NoTeXIndent")
else
  let s:TeXIndent = function(substitute(&indentexpr, "()", "", ""))
endif

unlet b:did_indent
runtime indent/r.vim
let s:RIndent = function(substitute(&indentexpr, "()", "", ""))
let b:did_indent = 1

setlocal indentkeys=0{,0},!^F,o,O,e,},=\bibitem,=\item
setlocal indentexpr=GetRnowebIndent()

if exists("*GetRnowebIndent")
  finish
endif

function GetRnowebIndent()
  let curline = getline(".")
  if curline =~ '^<<.*>>=$' || curline =~ '^\s*@$'
    return 0
  endif
  if search("^<<", "bncW") > search("^@", "bncW")
    return s:RIndent()
  endif
  return s:TeXIndent()
endfunction

" vim: sw=2