Mercurial > vim

view src/testdir/test_messages.vim @ 12702:a99da335b6f1 v8.0.1229

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1229: condition in vim_str2nr() is always true commit https://github.com/vim/vim/commit/9a91c7a1f9134f799b8672a4e3844781263e8cf3 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Oct 28 15:38:40 2017 +0200 patch 8.0.1229: condition in vim_str2nr() is always true Problem: Condition in vim_str2nr() is always true. (Nikolai Pavlov) Solution: Remove the condition. (Closes https://github.com/vim/vim/issues/2259)
author Christian Brabandt <cb@256bit.org>
date Sat, 28 Oct 2017 15:45:04 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction