Mercurial > vim

view runtime/syntax/services.vim @ 12549:62e8cef76508 v8.0.1153

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1153: no tests for diff_hlID() and diff_filler() commit https://github.com/vim/vim/commit/97fbc404fc56f76df12b2d2658b1d6efda28d5dd Author: Bram Moolenaar <Bram@vim.org> Date: Tue Sep 26 19:41:46 2017 +0200 patch 8.0.1153: no tests for diff_hlID() and diff_filler() Problem: No tests for diff_hlID() and diff_filler(). Solution: Add tests. (Dominique Pelle, closes https://github.com/vim/vim/issues/2156)
author Christian Brabandt <cb@256bit.org>
date Tue, 26 Sep 2017 19:45:04 +0200
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             services(5) - Internet network services list
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   servicesBegin     display '^'
                              \ nextgroup=servicesName,servicesComment

syn match   servicesName      contained display '[[:graph:]]\+'
                              \ nextgroup=servicesPort skipwhite

syn match   servicesPort      contained display '\d\+'
                              \ nextgroup=servicesPPDiv,servicesPPDivDepr
                              \ skipwhite

syn match   servicesPPDiv     contained display '/'
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesPPDivDepr contained display ','
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesProtocol  contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn match   servicesAliases   contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn keyword servicesTodo      contained TODO FIXME XXX NOTE

syn region  servicesComment   display oneline start='#' end='$'
                              \ contains=servicesTodo,@Spell

hi def link servicesTodo      Todo
hi def link servicesComment   Comment
hi def link servicesName      Identifier
hi def link servicesPort      Number
hi def link servicesPPDiv     Delimiter
hi def link servicesPPDivDepr Error
hi def link servicesProtocol  Type
hi def link servicesAliases   Macro

let b:current_syntax = "services"

let &cpo = s:cpo_save
unlet s:cpo_save