Mercurial > vim

view src/testdir/test_messages.vim @ 10829:8233f8f3f7ae v8.0.0304

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0304: assign test fails in the GUI commit https://github.com/vim/vim/commit/1fb0d49803b4f57025ed6a43b1f5b9eb91524645 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Feb 4 21:50:19 2017 +0100 patch 8.0.0304: assign test fails in the GUI Problem: Assign test fails in the GUI. Solution: Skip the test for setting t_k1.
author Christian Brabandt <cb@256bit.org>
date Sat, 04 Feb 2017 22:00:04 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction