Mercurial > vim

view src/testdir/test_messages.vim @ 10627:fb9c28aca006 v8.0.0203

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0203: order of complication flags is sometimes wrong commit https://github.com/vim/vim/commit/6e78e27b8aace2e4c2412bfc4de6567509258d28 Author: Bram Moolenaar <Bram@vim.org> Date: Tue Jan 17 19:20:15 2017 +0100 patch 8.0.0203: order of complication flags is sometimes wrong Problem: Order of complication flags is sometimes wrong. Solution: Put interface-specific flags before ALL_CFLAGS. (idea by Yousong Zhou, closes #1100)
author Christian Brabandt <cb@256bit.org>
date Tue, 17 Jan 2017 19:30:04 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction