Mercurial > vim

view runtime/syntax/udevperm.vim @ 10587:98ee4f22da6e v8.0.0183

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0183: ubsan warns for unaligned address commit https://github.com/vim/vim/commit/7173b47958a238bb07f80b8f26fb232b0ea69b4a Author: Bram Moolenaar <Bram@vim.org> Date: Sat Jan 14 17:04:38 2017 +0100 patch 8.0.0183: ubsan warns for unaligned address Problem: Ubsan warns for using a pointer that is not aligned. Solution: First copy the address. (Yegappan Lakshmanan)
author Christian Brabandt <cb@256bit.org>
date Sat, 14 Jan 2017 17:15:04 +0100
parents 1f3b1021f002
children 1218c5353e2b
line wrap: on
line source

" Vim syntax file
" Language:         udev(8) permissions file
" Maintainer:       Nikolai Weibull <now@bitwi.se>
" Latest Revision:  2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   udevpermBegin       display '^' nextgroup=udevpermDevice

syn match   udevpermDevice      contained display '[^:]\+'
                                \ contains=udevpermPattern
                                \ nextgroup=udevpermUserColon

syn match   udevpermPattern     contained '[*?]'
syn region  udevpermPattern     contained start='\[!\=' end='\]'
                                \ contains=udevpermPatRange

syn match   udevpermPatRange    contained '[^[-]-[^]-]'

syn match   udevpermUserColon   contained display ':'
                                \ nextgroup=udevpermUser

syn match   udevpermUser        contained display '[^:]\+'
                                \ nextgroup=udevpermGroupColon

syn match   udevpermGroupColon  contained display ':'
                                \ nextgroup=udevpermGroup

syn match   udevpermGroup       contained display '[^:]\+'
                                \ nextgroup=udevpermPermColon

syn match   udevpermPermColon   contained display ':'
                                \ nextgroup=udevpermPerm

syn match   udevpermPerm        contained display '\<0\=\o\+\>'
                                \ contains=udevpermOctalZero

syn match   udevpermOctalZero   contained display '\<0'
syn match   udevpermOctalError  contained display '\<0\o*[89]\d*\>'

syn keyword udevpermTodo        contained TODO FIXME XXX NOTE

syn region  udevpermComment     display oneline start='^\s*#' end='$'
                                \ contains=udevpermTodo,@Spell

hi def link udevpermTodo        Todo
hi def link udevpermComment     Comment
hi def link udevpermDevice      String
hi def link udevpermPattern     SpecialChar
hi def link udevpermPatRange    udevpermPattern
hi def link udevpermColon       Normal
hi def link udevpermUserColon   udevpermColon
hi def link udevpermUser        Identifier
hi def link udevpermGroupColon  udevpermColon
hi def link udevpermGroup       Type
hi def link udevpermPermColon   udevpermColon
hi def link udevpermPerm        Number
hi def link udevpermOctalZero   PreProc
hi def link udevpermOctalError  Error

let b:current_syntax = "udevperm"

let &cpo = s:cpo_save
unlet s:cpo_save