Mercurial > vim

view runtime/syntax/group.vim @ 10573:3f777388b6ad v8.0.0176

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0176: cannot use :change inside a function definition commit https://github.com/vim/vim/commit/70bcd7336f9f19304f32c52a86ed5b4b3de852c2 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Jan 12 22:20:54 2017 +0100 patch 8.0.0176: cannot use :change inside a function definition Problem: Using :change in between :function and :endfunction fails. Solution: Recognize :change inside a function. (ichizok, closes https://github.com/vim/vim/issues/1374)
author Christian Brabandt <cb@256bit.org>
date Thu, 12 Jan 2017 22:30:04 +0100
parents 536aa8b0c934
children 1218c5353e2b
line wrap: on
line source

" Vim syntax file
" Language:         group(5) user group file
" Maintainer:       Nikolai Weibull <now@bitwi.se>
" Latest Revision:  2012-08-05

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   groupBegin          display '^' nextgroup=groupName

syn match   groupName           contained display '[^:]\+'
                                \ nextgroup=groupPasswordColon

syn match   groupPasswordColon  contained display ':'
                                \ nextgroup=groupPassword,groupShadow

syn match   groupPassword       contained display '[^:]*'
                                \ nextgroup=groupGIDColon

syn match   groupShadow         contained display '[x*]' nextgroup=groupGIDColon

syn match   groupGIDColon       contained display ':' nextgroup=groupGID

syn match   groupGID            contained display '\d*'
                                \ nextgroup=groupUserListColon

syn match   groupUserListColon  contained display ':' nextgroup=groupUserList

syn match   groupUserList       contained '[^,]\+'
                                \ nextgroup=groupUserListSep

syn match   groupUserListSep    contained display ',' nextgroup=groupUserList

hi def link groupDelimiter      Normal
hi def link groupName           Identifier
hi def link groupPasswordColon  groupDelimiter
hi def link groupPassword       Number
hi def link groupShadow         Special
hi def link groupGIDColon       groupDelimiter
hi def link groupGID            Number
hi def link groupUserListColon  groupDelimiter
hi def link groupUserList       Identifier
hi def link groupUserListSep    groupDelimiter

let b:current_syntax = "group"

let &cpo = s:cpo_save
unlet s:cpo_save