Mercurial > vim

view src/testdir/test_messages.vim @ 9391:4c40631238e4 v7.4.1977

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
commit https://github.com/vim/vim/commit/bde9810d6103ffe3a22a9330021cb21db1ed1792 Author: Bram Moolenaar <Bram@vim.org> Date: Fri Jul 1 20:03:42 2016 +0200 patch 7.4.1977 Problem: With 64 bit changes don't need three calls to sprintf(). Solution: Simplify the code, use vim_snprintf(). (Ken Takata)
author Christian Brabandt <cb@256bit.org>
date Fri, 01 Jul 2016 20:15:05 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction