Mercurial > vim

view runtime/plugin/manpager.vim @ 29102:fd9006d6ddcf v8.2.5072

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.5072: using uninitialized value and freed memory in spell command Commit: https://github.com/vim/vim/commit/2813f38e021c6e6581c0c88fcf107e41788bc835 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Jun 9 19:54:24 2022 +0100 patch 8.2.5072: using uninitialized value and freed memory in spell command Problem: Using uninitialized value and freed memory in spell command. Solution: Initialize "attr". Check for empty line early.
author Bram Moolenaar <Bram@vim.org>
date Thu, 09 Jun 2022 21:00:04 +0200
parents f3ec3c57e070
children 1e9e9d89f0ee
line wrap: on
line source

" Vim plugin for using Vim as manpager.
" Maintainer: Enno Nagel <ennonagel+vim@gmail.com>
" Last Change: 2022 Jun 05

command! -nargs=0 MANPAGER call s:ManPager() | delcommand MANPAGER

function s:ManPager()
  " global options, keep these to a minimum to avoid side effects
  if &compatible
    set nocompatible
  endif
  if exists('+viminfofile')
    set viminfofile=NONE
  endif
  set noswapfile 

  setlocal ft=man
  runtime ftplugin/man.vim
  setlocal buftype=nofile bufhidden=hide iskeyword+=: modifiable

  " Emulate 'col -b'
  silent! keepj keepp %s/\v(.)\b\ze\1?//ge

  " Remove ansi sequences
  silent! keepj keepp %s/\v\e\[%(%(\d;)?\d{1,2})?[mK]//ge

  " Remove empty lines above the header
  call cursor(1, 1)
  let n = search(".*(.*)", "c")
  if n > 1
    exe "1," . n-1 . "d"
  endif
  setlocal nomodifiable nomodified readonly nowrite

  syntax on
endfunction