Mercurial > vim

view src/testdir/test_changelist.vim @ 13280:fbda23eb0996 v8.0.1514

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1514: getting the list of changes is not easy commit https://github.com/vim/vim/commit/07ad816525da67cab3c0db21d1286d221dbc7477 Author: Bram Moolenaar <Bram@vim.org> Date: Tue Feb 13 13:59:59 2018 +0100 patch 8.0.1514: getting the list of changes is not easy Problem: Getting the list of changes is not easy. Solution: Add the getchangelist() function. (Yegappan Lakshmanan, closes #2634)
author Christian Brabandt <cb@256bit.org>
date Tue, 13 Feb 2018 14:15:05 +0100
parents
children 3f3d9ed211b2
line wrap: on
line source

" Tests for the changelist functionality

" Tests for the getchangelist() function
func Test_getchangelist()
  if !has("jumplist")
    return
  endif

  bwipe!
  enew
  call assert_equal([], getchangelist(10))
  call assert_equal([[], 0], getchangelist(bufnr('%')))

  call writefile(['line1', 'line2', 'line3'], 'Xfile1.txt')
  call writefile(['line1', 'line2', 'line3'], 'Xfile2.txt')

  edit Xfile1.txt
  exe "normal 1Goline\<C-G>u1.1"
  exe "normal 3Goline\<C-G>u2.1"
  exe "normal 5Goline\<C-G>u3.1"
  normal g;
  call assert_equal([[
	      \ {'lnum' : 2, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 4, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 6, 'col' : 4, 'coladd' : 0}], 2],
	      \ getchangelist(bufnr('%')))

  hide edit Xfile2.txt
  exe "normal 1GOline\<C-G>u1.0"
  exe "normal 2Goline\<C-G>u2.0"
  call assert_equal([[
	      \ {'lnum' : 1, 'col' : 6, 'coladd' : 0},
	      \ {'lnum' : 3, 'col' : 6, 'coladd' : 0}], 2],
	      \ getchangelist(bufnr('%')))
  hide enew

  call assert_equal([[
	      \ {'lnum' : 2, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 4, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 6, 'col' : 4, 'coladd' : 0}], 3], getchangelist(2))
  call assert_equal([[
	      \ {'lnum' : 1, 'col' : 6, 'coladd' : 0},
	      \ {'lnum' : 3, 'col' : 6, 'coladd' : 0}], 2], getchangelist(3))

  bwipe!
  call delete('Xfile1.txt')
  call delete('Xfile2.txt')
endfunc