Mercurial > vim

view runtime/syntax/gdresource.vim @ 32443:fbcf40a2bf58 v9.0.1553

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.1553: CI: using slightly outdated gcc version Commit: https://github.com/vim/vim/commit/b6a19594b29a7d4f33a1f4324a0579df61f48d06 Author: Philip H <47042125+pheiduck@users.noreply.github.com> Date: Sat May 13 18:05:20 2023 +0100 patch 9.0.1553: CI: using slightly outdated gcc version Problem: CI: using slightly outdated gcc version. Solution: Use "brew" to get a more recent gcc version. (closes https://github.com/vim/vim/issues/12391)
author Bram Moolenaar <Bram@vim.org>
date Sat, 13 May 2023 19:15:03 +0200
parents ebed259f919f
children
line wrap: on
line source

" Vim syntax file for Godot resource (scenes)
" Language:     gdresource
" Maintainer:   Maxim Kim <habamax@gmail.com>
" Filenames:    *.tscn, *.tres
" Website:      https://github.com/habamax/vim-gdscript

if exists("b:current_syntax")
    finish
endif

let s:keepcpo = &cpo
set cpo&vim

syn match gdResourceNumber "\<0x\%(_\=\x\)\+\>"
syn match gdResourceNumber "\<0b\%(_\=[01]\)\+\>"
syn match gdResourceNumber "\<\d\%(_\=\d\)*\>"
syn match gdResourceNumber "\<\d\%(_\=\d\)*\%(e[+-]\=\d\%(_\=\d\)*\)\=\>"
syn match gdResourceNumber "\<\d\%(_\=\d\)*\.\%(e[+-]\=\d\%(_\=\d\)*\)\=\%(\W\|$\)\@="
syn match gdResourceNumber "\%(^\|\W\)\@1<=\%(\d\%(_\=\d\)*\)\=\.\d\%(_\=\d\)*\%(e[+-]\=\d\%(_\=\d\)*\)\=\>"

syn keyword gdResourceKeyword true false

syn region gdResourceString
      \ start=+[uU]\="+ end='"' skip='\\\\\|\\"'
      \ contains=@Spell keepend

" Section
syn region gdResourceSection matchgroup=gdResourceSectionDelimiter
      \ start='^\[' end=']\s*$'
      \ oneline keepend
      \ contains=gdResourceSectionName,gdResourceSectionAttribute

syn match gdResourceSectionName '\[\@<=\S\+' contained skipwhite
syn match gdResourceSectionAttribute '\S\+\s*=\s*\S\+'
      \ skipwhite keepend contained
      \ contains=gdResourceSectionAttributeName,gdResourceSectionAttributeValue
syn match gdResourceSectionAttributeName '\S\+\ze\(\s*=\)' skipwhite contained
syn match gdResourceSectionAttributeValue '\(=\s*\)\zs\S\+\ze' skipwhite
      \ contained
      \ contains=gdResourceString,gdResourceNumber,gdResourceKeyword


" Section body
syn match gdResourceAttribute '^\s*\S\+\s*=.*$'
      \ skipwhite keepend
      \ contains=gdResourceAttributeName,gdResourceAttributeValue

syn match gdResourceAttributeName '\S\+\ze\(\s*=\)' skipwhite contained
syn match gdResourceAttributeValue '\(=\s*\)\zs.*$' skipwhite
      \ contained
      \ contains=gdResourceString,gdResourceNumber,gdResourceKeyword


hi def link gdResourceNumber Constant
hi def link gdResourceKeyword Constant
hi def link gdResourceSectionName Statement
hi def link gdResourceSectionDelimiter Delimiter
hi def link gdResourceSectionAttributeName Type
hi def link gdResourceAttributeName Identifier
hi def link gdResourceString String

let b:current_syntax = "gdresource"

let &cpo = s:keepcpo
unlet s:keepcpo