Mercurial > vim

view src/testdir/test_changelist.vim @ 28299:fae7d94220e3 v8.2.4675

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.4675: no error for missing expression after :elseif Commit: https://github.com/vim/vim/commit/fa010cdfb115fd2f6bae7ea6f6e63be906b5e347 Author: Bram Moolenaar <Bram@vim.org> Date: Sun Apr 3 16:13:07 2022 +0100 patch 8.2.4675: no error for missing expression after :elseif Problem: No error for missing expression after :elseif. (Ernie Rael) Solution: Check for missing expression. (closes https://github.com/vim/vim/issues/10068)
author Bram Moolenaar <Bram@vim.org>
date Sun, 03 Apr 2022 17:15:02 +0200
parents 255bc9a08e58
children 1170b35651a5
line wrap: on
line source

" Tests for the changelist functionality

" Tests for the getchangelist() function
func Test_getchangelist()
  bwipe!
  enew
  call assert_equal([], 10->getchangelist())
  call assert_equal([[], 0], getchangelist())

  call writefile(['line1', 'line2', 'line3'], 'Xfile1.txt')
  call writefile(['line1', 'line2', 'line3'], 'Xfile2.txt')

  edit Xfile1.txt
  exe "normal 1Goline\<C-G>u1.1"
  exe "normal 3Goline\<C-G>u2.1"
  exe "normal 5Goline\<C-G>u3.1"
  normal g;
  call assert_equal([[
	      \ {'lnum' : 2, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 4, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 6, 'col' : 4, 'coladd' : 0}], 2],
	      \ getchangelist('%'))

  hide edit Xfile2.txt
  exe "normal 1GOline\<C-G>u1.0"
  exe "normal 2Goline\<C-G>u2.0"
  call assert_equal([[
	      \ {'lnum' : 1, 'col' : 6, 'coladd' : 0},
	      \ {'lnum' : 3, 'col' : 6, 'coladd' : 0}], 2],
	      \ getchangelist('%'))
  hide enew

  call assert_equal([[
	      \ {'lnum' : 2, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 4, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 6, 'col' : 4, 'coladd' : 0}], 3], getchangelist(2))
  call assert_equal([[
	      \ {'lnum' : 1, 'col' : 6, 'coladd' : 0},
	      \ {'lnum' : 3, 'col' : 6, 'coladd' : 0}], 2], getchangelist(3))

  bwipe!
  call delete('Xfile1.txt')
  call delete('Xfile2.txt')
endfunc

" vim: shiftwidth=2 sts=2 expandtab