Mercurial > vim

view src/testdir/test_messages.vim @ 10694:fa6c4825a1c4 v8.0.0237

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0237: when 'wildoptions' is "tagfile" completion may not work commit https://github.com/vim/vim/commit/ba47b51ff88d91c9bb5aa522183e23a656865697 Author: Bram Moolenaar <Bram@vim.org> Date: Tue Jan 24 21:18:19 2017 +0100 patch 8.0.0237: when 'wildoptions' is "tagfile" completion may not work Problem: When setting wildoptions=tagfile the completion context is not set correctly. (desjardins) Solution: Check for EXPAND_TAGS_LISTFILES. (Christian Brabandt, closes #1399)
author Christian Brabandt <cb@256bit.org>
date Tue, 24 Jan 2017 21:30:04 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction