Mercurial > vim

view src/testdir/test_scrollbind.vim @ 16133:eb087f8a26a8 v8.1.1071

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1071: cannot get composing characters from the screen commit https://github.com/vim/vim/commit/2912abb3a2fd72074e3901c8ae1d4a77ce764675 Author: Bram Moolenaar <Bram@vim.org> Date: Fri Mar 29 14:16:42 2019 +0100 patch 8.1.1071: cannot get composing characters from the screen Problem: Cannot get composing characters from the screen. Solution: Add screenchars() and screenstring(). (partly by Ozaki Kiichi, closes #4059)
author Bram Moolenaar <Bram@vim.org>
date Fri, 29 Mar 2019 14:30:05 +0100
parents 0240e7e3d736
children 687ab2b5252b
line wrap: on
line source

" Test for 'scrollbind' causing an unexpected scroll of one of the windows.
func Test_scrollbind()
  " We don't want the status line to cause problems:
  set laststatus=0
  let totalLines = &lines * 20
  let middle = totalLines / 2
  new | only
  for i in range(1, totalLines)
      call setline(i, 'LINE ' . i)
  endfor
  exe string(middle)
  normal zt
  normal M
  aboveleft vert new
  for i in range(1, totalLines)
      call setline(i, 'line ' . i)
  endfor
  exe string(middle)
  normal zt
  normal M
  " Execute the following two commands at once to reproduce the problem.
  setl scb | wincmd p
  setl scb
  wincmd w
  let topLineLeft = line('w0')
  wincmd p
  let topLineRight = line('w0')
  setl noscrollbind
  wincmd p
  setl noscrollbind
  call assert_equal(0, topLineLeft - topLineRight)
endfunc